tracker.ino

Go to the documentation of this file.

/*
   Copyright (C) 2018 SFini

   This program is free software: you can redistribute it and/or modify
   it under the terms of the GNU General Public License as published by
   the Free Software Foundation, either version 3 of the License, or
   (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/
#include <SoftwareSerial.h>
#include <ArduinoOTA.h>
#include <FS.h>

#define SIM808_CONNECTED

#include "Config.h"
#define USE_CONFIG_OVERRIDE 
#ifdef USE_CONFIG_OVERRIDE
  #include "ConfigOverride.h"
#endif

#include "Utils.h"
#include "StringList.h"
#include "Gps.h"
#include "Options.h"
#include "Data.h"
#include "Voltage.h"
#include "DeepSleep.h"
#include "WebServer.h"
#include "GsmPower.h"
#include "GsmGps.h"
#include "SmsCmd.h"
#include "Mqtt.h"
#include "BME280.h"


#define     PIN_POWER     D3                                        
#define     PIN_BME_GRND  D4                                        
#define     BME_ADDRESS   0x77                                      
#define     PIN_TX        D5                                        
#define     PIN_RX        D6                                        
                                                                 
MyOptions   myOptions;                                              
MyData      myData;                                                 
MyVoltage   myVoltage(myOptions, myData);                           
MyDeepSleep myDeepSleep(myOptions, myData);                         
MyWebServer myWebServer(myOptions, myData);                         
MyBME280    myBME280(myOptions, myData, PIN_BME_GRND, BME_ADDRESS); 

#ifdef SIM808_CONNECTED
   MyGsmPower  myGsmPower(myData, PIN_POWER);                       
   MyGsmGps    myGsmGps(myOptions, myData, PIN_RX, PIN_TX);         
   MySmsCmd    mySmsCmd(myGsmGps, myOptions, myData);               
   MyMqtt      myMqtt(myGsmGps.gsmClient, myOptions, myData);       
#else                                                               
   MyMqtt      myMqtt(MyWebServer::server.wifiClient(), myOptions, myData); 
#endif                                                          

bool        gsmHasPower = false;                                    
bool        isStarting  = false;                                    
bool        isStopping  = false;                                    

void yield(void)
{
   ESP.wdtFeed();
}

void myDebugInfo(String info, bool fromWebserver, bool newline)
{
   static bool lastNewLine = true;
   
   if (newline || lastNewLine != newline) {
      String secs = String(secondsSincePowerOn()) + F(": ");

      myData.logInfos.addTail(secs + info);
      if (!lastNewLine) {
         Serial.println("");
      }
      Serial.println(secs + info);
   } else {
      String tmp = myData.logInfos.removeTail();

      Serial.print(tmp + info);
      myData.logInfos.addTail(tmp + info);
   }
   lastNewLine = newline;

   if (!fromWebserver) {
      myWebServer.handleClient();   
      myWebServer.handleClient();   
      myWebServer.handleClient();   
   } 
   delay(1);
   yield();
}

void myDelayLoop()
{
   myWebServer.handleClient();   
   myWebServer.handleClient();   
   myWebServer.handleClient(); 
   delay(1);
   yield();
}

long secondsSincePowerOn()
{
   return myData.secondsSincePowerOn();
}

void setup() 
{
   Serial.begin(115200); 
   delay(1000);

   MyDbg(F("Start SnorkTracker ..."));

#ifdef SIM808_CONNECTED
   myGsmPower.begin();
#endif
   SPIFFS.begin();
   myOptions.load();
   myVoltage.begin();

   // Back to deep sleep?
   myDeepSleep.begin();

   // no deep sleep!
   myWebServer.begin();
   myMqtt.begin();
#ifdef SIM808_CONNECTED
   mySmsCmd.begin();
#endif
   myBME280.begin();
}

void loop() 
{
   myVoltage.readVoltage();
   myBME280.readValues();

   myWebServer.handleClient();
   
   if (myData.isOtaActive) {
      ArduinoOTA.handle();    
   }

#ifndef SIM808_CONNECTED
   if (myOptions.isMqttEnabled) {
      myMqtt.handleClient();
   }

   if (!myMqtt.waitingForMqtt()) {
      if (myDeepSleep.haveToSleep()) {
         WiFi.disconnect();
         WiFi.mode(WIFI_OFF);
         yield();
         myDeepSleep.sleep();
      }
   }
#else
   if (!myData.consoleCmds.isEmpty()) {
      String cmd = myData.consoleCmds.removeHead();

      myGsmGps.sendAT(cmd);
   }

   // Starting gsm ?
   if (myOptions.powerOn && !gsmHasPower) {
      if (!isStarting && !isStopping) {
         isStarting = true;
         myGsmPower.on(); 
         gsmHasPower = true;
         if (!myGsmGps.begin()) {
            myGsmGps.stop();
            myGsmPower.off();
            gsmHasPower = false;
         }
         isStarting = false;
      }
   }

   // Stopping gsm ?
   if (!myOptions.powerOn && gsmHasPower) {
      if (!isStarting && !isStopping) {
         isStopping = true;
         myGsmGps.stop();
         myGsmPower.off();
         gsmHasPower = false;
         isStopping  = false;   
      }
   }

   // Do gsm processing.
   if (gsmHasPower && !isStarting && !isStopping) {
      myGsmGps.handleClient();

      // No sms or mqtt if we are waiting for a gps position.
      // Otherwise we are sending invalid gps values.
      if (!myGsmGps.waitingForGps()) {
         if (myOptions.isSmsEnabled) {
            mySmsCmd.handleClient();
         }
         if (myOptions.isMqttEnabled) {
            myMqtt.handleClient();
         }
      }
   }

   // Deep Sleep?
   // (No deep sleep if we are waiting for a valid gps position).
   if (!myGsmGps.waitingForGps() && !myMqtt.waitingForMqtt()) {
      if (myDeepSleep.haveToSleep()) {
         if (myData.isGsmActive) {
            myGsmGps.stop();
         }
         myGsmPower.off();
         WiFi.disconnect();
         WiFi.mode(WIFI_OFF);
         yield();
         myDeepSleep.sleep();
      }
   }

#endif

   yield();
   delay(10); 
}